资料篇-ASP发布接口代码制作范例

一、ASP发布接口代码制作范例
直接入库的接口或使用网站发布的接口原理是一样的，本例示范了使用ASP程序语言制作的接口在发布过程需要包含的几个主要部分：
<%@ LANGUAGE = VBScript CodePage = 936%>
<%

'===========================================初始化与数据库设置开始===============================================
Response.Buffer = True
Session.LCID = 2052 '## 中国地区LCID

Dim SqlNowString
Dim Conn,Db,MyDbPath
'可修改设置一：========================定义数据库类别，1为SQL数据库，0为Access数据库=============================
Const IsSqlDataBase = 0
MyDbPath = "/"


If IsSqlDataBase = 1 Then

'必修改设置二：========================SQL数据库设置=============================================================

'sql数据库连接参数：数据库名(SqlDatabaseName)、用户密码(SqlPassword)、用户名(SqlUsername)、

'连接名(SqlLocalName)（本地用local，外地用IP）

	Const SqlDatabaseName = ""
	Const SqlPassword = ""
	Const SqlUsername = ""
	Const SqlLocalName = "(local)"
'================================================================================================================
	SqlNowString = "GetDate()"
	Sqlwildcard="%"
Else
'必修改设置三：========================Access数据库设置==========================================================

	Db = "data.mdb"

'================================================================================================================

	SqlNowString = "Now()"
	Sqlwildcard="%"

End If
Const IsDeBug = 1

Sub ConnectionDatabase
	Dim ConnStr
	If IsSqlDataBase = 1 Then
		ConnStr = "Provider = Sqloledb; User ID = " & SqlUsername & "; Password = " & SqlPassword & "; Initial Catalog = " & SqlDatabaseName & "; Data Source = " & SqlLocalName & ";"
	Else
		ConnStr = "Provider = Microsoft.Jet.OLEDB.4.0;Data Source = " & Server.MapPath(MyDbPath & db)
	End If
	On Error Resume Next
	Set conn =CreateObject("ADODB.Connection")
	conn.open ConnStr
	If Err Then
		err.Clear
		Set Conn = Nothing
		Response.Write "[err]数据库连接出错，请检查连接字串。[/err]" '返回失败信息
		Response.End
	End If
End Sub
Sub CloseDatabase

	On Error Resume Next
	If IsObject(Conn) Then
		Conn.Close
	end if
	Set Conn = Nothing

End Sub
'==========================================初始化与数据库设置结束================================================

'====================================定义参数，标题、正文、附加参数1、附加参数2==================================

DIM title,content,var1,var2 

'==========================================ET通过POST方式传递参数================================================
title=REQUEST.Form("title")
content=REQUEST.Form("content")
var1=REQUEST.Form("var1")
var2=REQUEST.Form("var2")

'============================================数据校验和整理开始==================================================
'
'根据需要对获取到的参数数据进行的各种校验或处理
'
'============================================数据校验和整理结束==================================================


'=============================================将数据插入数据库===================================================
ConnectionDatabase

On Error Resume Next
DIM str
Conn.BeginTrans  
str="insert into table1(title,content,var1,var2) values('"&title&"','"&content&"','"&var1&"','"&var2&"')"
conn.execute(str)  
if conn.Errors.Count>0 then  
	conn.Errors.Clear  
'===================================如果插入数据操作失败，则事务向前回滚=========================================
	conn.RollBackTrans  
	Response.Write "[err]数据写入失败，请检查数据合法性[/err]" '=======[err][/err]是ET发布失败标志====
else  

'===================================如果整个事务操作执行正确，则提交事务========================================= 
	Conn.CommitTrans   			
	response.Write "[ok]"	'=========================[ok]是ET发布成功标志============================
end if
CloseDatabase


%>